Tweets that mention F1 drivers sorted by date.

PREFIX xlime: <http://xlime-project.org/vocab/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

select distinct ?media ?racer ?date where {
?s xlime:hasAnnotation ?a .
?s dcterms:source ?media .
?s dcterms:publisher <http://www.twitter.com/> .
?s dcterms:created ?date .
?a xlime:hasEntity ?racer .
?racer rdf:type dbpedia-owl:FormulaOneRacer .
} 
order by desc(?date) limit 100

Which teams sponsored by Nike Inc. are most present in news and social media?

PREFIX xlime: <http://xlime-project.org/vocab/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

select count(distinct ?media) as ?count ?entity where {
?s xlime:hasAnnotation ?a.
?s dcterms:source ?media.
?a xlime:hasEntity ?entity.
?entity2 dbpedia-owl:team ?entity.
?entity2 dbpprop:su <http://dbpedia.org/resource/Nike,_Inc.> .
} group by ?entity order by desc(?count)

News and social media in English about politicians of the UKIP party who were born before 1960.

PREFIX xlime: <http://xlime-project.org/vocab/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

select distinct ?media ?politician where {
?s xlime:hasAnnotation ?a .
?s dcterms:source ?media .
?s dcterms:language "en" .
?a xlime:hasEntity ?politician .
?politician dbpedia-owl:party dbpedia:UK_Independence_Party .
?politician dbpedia-owl:birthDate ?d .
FILTER (?d < "1960-01-01"^^xsd:date) .
}

How often was Barack Obama and how often was ISIS mentioned since December 1st?

PREFIX xlime: <http://xlime-project.org/vocab/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

select count(?media) as ?count ?entity where {
?s xlime:hasAnnotation ?a.
?s dcterms:source ?media.
?s dcterms:created ?date.
?a xlime:hasEntity ?entity.
FILTER (?date > "2014-12-01"^^xsd:date && ?date < now()).
FILTER (?entity = dbpedia:Barack_Obama || ?entity = dbpedia:Isis).
} group by ?entity

The latest about Greece in German.

PREFIX xlime: <http://xlime-project.org/vocab/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>

select ?media ?date where {
?s xlime:hasAnnotation ?a .
?s dcterms:source ?media .
?s dcterms:created ?date .
?a xlime:hasEntity dbpedia:Greece . 
?s dcterms:language "de" .
} order by desc(?date) limit 1